如何重命名文件并将其移动到新目录

问题描述：

我想将以扩展名.txt上传到另一台服务器的文件重命名为.txt_mvd，然后移动到其他目录以Windows批处理模式进行归档.任何人都可以提供有关Windows批处理脚本的帮助吗?

I would like to rename files that are uploaded to another server from extension .txt to .txt_mvd and move to a different directory for archiving in a Windows batch mode. Can anyone help with what the windows batch script should be?

谢谢.

答

下面是代码

FOR  /R C:\your_folder %%d  IN  (*.txt)  DO  (
    ren %%d %%~nd.txt_mvd
)

%% d是完整的文件名+路径
%%〜nd仅返回不带扩展名的文件名
使用/R参数，它将扫描文件夹和子文件夹

%%d is the full file name + path
%%~nd return only the file name without the extension
Using the /R parameter, it will scan folder and subfolder

更新1

以下代码应按要求工作.
我添加了一个忽略子文件夹的IF.

The following code should work as required.
I've added an IF that ignore the subfolders.

FOR  /R E:\your_folder\ %%d  IN  (*.*)  DO  (
    IF %%~dpd==E:\your_folder\ (
        ren %%d %%~nd.txt_mvd
    )
)

更新2

固定代码

FOR  /R E:\your_folder\ %%d  IN  (*.txt)  DO  (
    IF %%~dpd==E:\your_folder\ (
        ren %%d %%~nd.txt_mvd
    )
)

更新3
这是脚本的更通用化和参数化的版本.
根据需要更改起始参数(代码的前4行).
该脚本首先在起始文件夹(第3参数)中重命名您选择的文件(第1参数)，将扩展名更改为新的扩展名(第2参数)，然后将重命名的文件移动到您选择的文件夹中(第4参数).

UPDATE 3
Here is a more generalized and parametrized version of the script.
Change the starting parameter to your need (the first 4 lines of code).
This script first rename the files you choose (1st parameter) in your starting folder (3rd parameter), change the extension to the new one (2nd parameter), and then move the renamed files in the folder of your choice (4th parameter).

set Extension_of_file_you_want_to_renamne_and_move=txt
set New_extension_of_moved_files=txt_mvd

set Folder_that_contain_your_files=C:\Your_starting_folder\
set Folder_where_to_move_your_files=C:\Your_destnation_folder\

FOR  /R %Folder_that_contain_your_files% %%d  IN  (*.%Extension_of_file_you_want_to_renamne_and_move%)  DO  (
    IF %%~dpd==%Folder_that_contain_your_files% (
    IF %%~xd==.%Extension_of_file_you_want_to_renamne_and_move% (
        ren "%%~d" "%%~nd.%New_extension_of_moved_files%"
        move "%%~dpnd.%New_extension_of_moved_files%" "%Folder_where_to_move_your_files%"
        )
    )
)

更改参数时请勿添加任何空格.
因此，请勿像这样更改参数:

when you change the parameter DON'T add any space.
So DON'T change the parameter like that:

set Folder_that_contain_your_files = c:\myFolder      <--- WRONG, WON'T WORK, there are unneeded space

相反，编写参数时不要多余的空间:

instead, write the parameter WITHOUT unneeded space:

set Folder_that_contain_your_files=c:\myFolder      <--- OK, THIS WILL WORK, there are no extra spaces

更新4
修复了代码，我添加了一些引号，如果文件夹名称中包含空格，没有引号，代码将无法正常工作.

UPDATE 4
Fixed the code, I've added some quotation marks, without them the code wont works if folder name contained spaces.

set Extension_of_file_you_want_to_renamne_and_move=txt
set New_extension_of_moved_files=txt_mvd

set Folder_that_contain_your_files=C:\Your_starting_folder\
set Folder_where_to_move_your_files=C:\Your_destnation_folder\

FOR  /R "%Folder_that_contain_your_files%" %%d  IN  (*.%Extension_of_file_you_want_to_renamne_and_move%)  DO  (
    IF "%%~dpd"=="%Folder_that_contain_your_files%" (
    IF %%~xd==.%Extension_of_file_you_want_to_renamne_and_move% (
        ren "%%~d" "%%~nd.%New_extension_of_moved_files%"
        move "%%~dpnd.%New_extension_of_moved_files%" "%Folder_where_to_move_your_files%"
        )
    )
)

如何重命名文件并将其移动到新目录

相关推荐