应力中的APDL命令源

　　当荷载作用在构件上时，荷载通过构件以内力的形式传递，为了描述内力在构件截面上的分布规律，必须引入一个内力的度量— 应力，单位为N/(m^2)或帕（Pa）。
　　单位面积上所受的力，就叫应力。杆件受拉（受压）时，就会产生垂直于杆件截面的应力，用σ 表示；杆件受剪时，就会产生平行于杆件截面的应力，为剪应力，用τ 表示。
　　图1-4所示，为一块无限大且中心有圆孔的平板，其厚度为1个单位，在x方向承受单向拉伸，其拉伸载荷为: q = 1MPa，已知材料的性能参数为: E = 2.0×10^5 MPa，泊松比v = 0.3。试求出A点在不同的网格划分条件下，其应力的变化过程。

FINISH
/CLEAR,START
*DIM,vs,,8               !定义4个8*1的数组
*DIM,num,,8
*DIM,x1,,8
*DIM,y1,,8
weight=1                 !定义正方形的边长
r=0.1                    !定义圆的半径
/PREP7                   !进入前处理器
ET,1,PLANE42
MP,EX,1,2e5                  !输入材料的弹性模量
MP,PRXY,1,0.3                !输入材料的泊松比
RECTNG,0,weight,0,weight,    !生成矩形面
CYL4,,,r                     !生成一个圆面
ASBA,1,2                     !从矩形面中减去圆面
NUMCMP,ALL                   !压缩实体的编号
FINISH
*DO,i,1,8                    !设置循环从1到5，循环变量为i
num(i)=i                     !循环次数记录在数组中
/PREP7                       
ACLEAR,1                     !清除面上的网格
N,,,r,,,,,                    !生成编号为1的节点即A点
LESIZE,4,0.1/i,,,,,,,1        !设置单元边的长度
LESIZE,5,0.1/i,,,,,,,1
LESIZE,2,0.1/i,,,,,,,1
LESIZE,1,0.1/i,,,,,,,1
AMAP,1,4,1,3,5                  !映射方式生成单元网格
NUMMRG,ALL,,,,LOW               !合并实体
NUMCMP,ALL                      !压缩实体编号
FINISH
/SOL
NSEL,S,LOC,X,0                 !选择X=0的所有节点
D,ALL,,,,,,UX,,,,,             !对选择的节点施加UX=0
ALLSEL,ALL                     !选择所有的实体   
NSEL,S,LOC,Y,0                 !选择Y=0的所有节点
D,ALL,,,,,,UY,,,,,             !对选择的节点施加UY=0
ALLSEL,ALL
SFL,1,PRES,-1,                  !对线1施加面载荷即q=1
SOLVE                           !求解运算
FINISH
/POST1                          !进入后处理器
*GET,vs(i),NODE,1,S,EQV        ! 取出节点1的Mises应力
FINISH
*ENDDO                            !完成循环
/SOLU
SMOOTH,num(1),vs(1),,3,x1(1),y1(1),2      !生成曲线
FINISH
/IMAGE,SAVE,Von_Stre,BMP                  !将曲线保存为位图文件
FINISH                                 !结束

效果如下：