asunit简略实例

package
{
    public class BankAccount
    {
          private var balance:Number=0;
          
          public function deposit(amount:Number):void{
               balance=balance+amount;
           }
          
          public function withdraw(amount:Number):void{
               balance=balance-amount;
           }
          
          public function getBalance():Number{
               return balance;
           }        
      }
}

package {
    import asunit.framework.TestCase;
        
    public class BankAccountTest extends TestCase {
          private var instance:BankAccount;
  
          /**
           * Constructor
           */
          public function BankAccountTest(testMethod:String) {
               super(testMethod);
           }
          
          /**
           * Set up instance of BankAccount to test with
           */
          protected override function setUp():void {
               instance = new BankAccount();
           }
          
          /**
           * Delete instance used for testing
           */
          protected override function tearDown():void {
               instance=null;
           }
          
          
          /**
           * Test BankAccount instantiation
           */
          public function testInstantiated():void {
               assertTrue("Example instantiated", instance is BankAccount);
           }
      
          
          /**
           * Test Deposit
           */
          public function testDeposit():void {
               instance.deposit(50);
               assertTrue("Balance on a new account after 50 deposit is 50", instance.getBalance() == 50);
               instance.deposit(25);
               assertEquals("Balance after 50 deposit and another 25 deposit is 75", 75,instance.getBalance());
               
           }
          
          /**
           * Test withdraw
           */
          public function testWithdraw():void {
               instance.deposit(100);
               instance.withdraw(50);
               assertTrue("Balance on a new account after 100 deposit and a 50 withdraw is 50", instance.getBalance() == 50);
               
       
           }
      }
}

package {
    import asunit.framework.TestSuite;
    import flash.display.Sprite;

    public class AllTests extends TestSuite {
          public function AllTests() {
                super();
               addTest(new BankAccountTest("testInstantiated"));
                addTest(new BankAccountTest("testDeposit"));
                addTest(new BankAccountTest("testWithdraw"));
            }
      }
}

package
{
  import asunit.textui.TestRunner;
  import flash.display.Sprite;

  public class Main extends Sprite
  {

    public function Main()
    {
      var unittests:TestRunner = new TestRunner();
      stage.addChild(unittests);
      unittests.start(AllTests, null, TestRunner.SHOW_TRACE);
    }
  }
}

public function testDeposit():void {
               instance.deposit(50);
               assertTrue("Balance on a new account after 50 deposit is 50", instance.getBalance() == 50);
               instance.deposit(25);
               assertEquals("Balance after 50 deposit and another 25 deposit is 75", 75,instance.getBalance());
               
           }