对TControl和TWinControl相同与不同之处的深刻理解（每一个WinControl就相当于扮演了整个Windows的窗口管理角色，主要是窗口显示和窗口大小）——TWinControl就两个作用（管理子控件的功能和调用句柄API的功能）

procedure TControl.SetBounds(ALeft, ATop, AWidth, AHeight: Integer);
begin
  if CheckNewSize(AWidth, AHeight) and // TControl的类函数
    ((ALeft <> FLeft) or (ATop <> FTop) or (AWidth <> FWidth) or (AHeight <> FHeight)) then
  begin
    InvalidateControl(Visible, False); // TControl的类函数，第二个参数表示暂时设置当前控件是透明的
    FLeft := ALeft;
    FTop := ATop;
    FWidth := AWidth;
    FHeight := AHeight;
    UpdateAnchorRules; // TControl的类函数，坐标和长宽设置完了，就要重新铆接一下
    // 属性设置完了，如果有API可以使之起作用就当场调用（关于显示部分，不需要句柄就有API使用，这是特殊情况）
    Invalidate; // TControl的类函数，调用TControl.InvalidateControl，再调用API声明无效区域
    // 此消息在TControl和TWinControl里都有相应的函数，图形控件使用消息再做一些自己力所能及的变化，Win控件使用消息调用类函数使之调用API真正起作用
    // 前者重新计算最大化最小化的限制和坞里的尺寸，后者使用API调整边框和控件自己的位置，当然也得重新计算最大化最小化的限制和坞里的尺寸（三明治手法） 
    Perform(WM_WINDOWPOSCHANGED, 0, 0);
    // Windows位置调整完了，还要重新对齐（本质是调用TWinControl.RequestAlign，然后调用API重新排列）
    // 但实际上是靠父Win控件重新排列自己，因为它自己没有能力拥有别的控件，当然也就不能实质上让所有控件对齐。
    RequestAlign; // TControl的虚函数，各WinControl的子类可自己改写，比如TCustomForm就改写了
    if not (csLoading in ComponentState) then Resize; // TControl的虚函数，简单调用程序员事件。子类一般不需要改写它。
  end;
end;

procedure TWinControl.SetBounds(ALeft, ATop, AWidth, AHeight: Integer);
var
  WindowPlacement: TWindowPlacement; // Windows结构类型，包含最大化最小化窗口位置等6项内容
begin
  if (ALeft <> FLeft) or (ATop <> FTop) or (AWidth <> FWidth) or (AHeight <> FHeight) then
  begin
    // 如果有句柄，并且不是最小化状态，就使用API立刻调整位置
    if HandleAllocated and not IsIconic(FHandle) then // API
      SetWindowPos(FHandle, 0, ALeft, ATop, AWidth, AHeight, SWP_NOZORDER + SWP_NOACTIVATE) // API，使用完毕后Windows自己会更改WindowPlacement里的数据
    else
    // 如果还没有句柄，或者处于最小化状态下，使用API更改WindowPlacement结构的值，以备下次调用API直接显示
    begin
      // 重新设置左上角坐标以及长宽
      FLeft := ALeft; // TControl的类属性，通用属性
      FTop := ATop;
      FWidth := AWidth;
      FHeight := AHeight;
      if HandleAllocated then
      begin
        // 取得窗口的位置信息
        WindowPlacement.Length := SizeOf(WindowPlacement);
        GetWindowPlacement(FHandle, @WindowPlacement); // API
        // 更改窗口的位置信息 
        WindowPlacement.rcNormalPosition := BoundsRect; // TControl的类属性，通用属性
        SetWindowPlacement(FHandle, @WindowPlacement); // API
      end;
    end;
    // super 前面使用API设置了真实的Windows窗口属性和Delphi控件属性后，可放心大胆的调用一些函数，不是TControl已经提供了通用逻辑，就是它自己定义了一些特殊的函数，可随便使用，直接产生效果，而不再依赖别人来完成某件事情。
    UpdateAnchorRules; // TControl类函数，通用函数
    RequestAlign; // TControl类函数，通用函数
  end;
end;

function TControl.GetDeviceContext(var WindowHandle: HWnd): HDC;
begin
  if Parent = nil then
    raise EInvalidOperation.CreateFmt(SParentRequired, [Name]);
  Result := Parent.GetDeviceContext(WindowHandle);// TWinControl的类函数，不仅仅设置DC，还从Delphi的FHandle设置参数句柄
  SetViewportOrgEx(Result, Left, Top, nil);       // API 用来改变视端口和窗口的原点，并都具有改变轴的效果，以致(0,0)不再指左上角
  IntersectClipRect(Result, 0, 0, Width, Height); // API 创建一个新的剪切区域，该区域是当前剪切区域和一个特定矩形的交集
end;

procedure TWinControl.CMColorChanged(var Message: TMessage);
begin
  inherited; // 自己的颜色变化起效果，是通过这句话来实现的，它包含了一连串的执行过程。父控件变化完了再通知子控件，风格很强势。
  FBrush.Color := FColor;
  NotifyControls(CM_PARENTCOLORCHANGED); // 第二个消息，组建消息并传播，通知子控件，但没有任何子控件响应
end;

procedure TWinControl.CMInvalidate(var Message: TMessage);
var
  I: Integer;
begin
  if HandleAllocated then
  begin
    if Parent <> nil then
      Parent.Perform(CM_INVALIDATE, 1, 0); // 第四个消息，递归，先通知父类（父类要提前通知）。Form1的Parent是Application，它没有响应。
    if Message.WParam = 0 then
    begin
      // API，第二个参数为NULL的话，则重画整个客户区；第三个参数TRUE则背景重绘。
      InvalidateRect(FHandle, nil, not (csOpaque in ControlStyle)); // 总算初步达到目的，使Form1失效，后面还要自绘
      { Invalidate child windows which use the parentbackground when themed }
      if ThemeServices.ThemesEnabled then
        for I := 0 to ControlCount - 1 do
          if csParentBackground in Controls[I].ControlStyle then // important
            Controls[I].Invalidate;
    end;
  end;
end;