怎么判断Access数据库的表中的字段是否存在索引

procedure GetIndexName(AIndexs: TStrings; const ATable: string; Connection: TADOConnection);
var
ADODataSet: TADODataSet;
FieldTable, FieldIndex, FieldColumn, FieldPrimary, FieldUnique: TField;
sText: string;
begin
ADODataSet := TADODataSet.Create(nil);
try
    Connection.OpenSchema(siIndexes, EmptyParam, EmptyParam, ADODataSet);
    FieldTable := ADODataSet.FindField('TABLE_NAME');
    FieldIndex := ADODataSet.FindField('INDEX_NAME');
    FieldColumn := ADODataSet.FindField('COLUMN_NAME');
    FieldPrimary := ADODataSet.FindField('PRIMARY_KEY');
    FieldUnique := ADODataSet.FindField('UNIQUE');
    ADODataSet.First;
    while not ADODataSet.Eof do
    begin
      if SameText(FieldTable.AsString, ATable) then
      begin
        if FieldPrimary.AsBoolean then
          sText := 'PrimaryKey'
        else if FieldUnique.AsBoolean then
          sText := 'Unique'
        else
          sText := '';
        if sText <> '' then
          sText := Format('%s (%s, %s)', [FieldIndex.AsString, FieldColumn.AsString, sText])
        else
          sText := Format('%s (%s)', [FieldIndex.AsString, FieldColumn.AsString]);
        AIndexs.Add(sText);
      end;
      ADODataSet.Next;
    end;
finally
    ADODataSet.Free;
end;
end;